Administrace komentářů

%u vs. %U je otázka nějakých kouzel s aliasy v Sambě - je možné se do Windows přihlašovat jiným jménem, než je jméno linuxového účtu, který se použije. Moc význam to nemá, v praxi je asi lepší vždy použít %u.

Normálně v linuxu nejde udělat, aby jedna skupina byla členem jiné skupiny.

Já používám logon skript takhle:

  logon script = logon.vbs %G

většina věcí v tom skriptu je shodná. Věci rozdílné pro různé skupiny se řeší tak, že VBS skript dostává jako 1. parametr název primární skupiny přihlášeného uživatele. Jinak jde udělat i:

  logon script = %G.vbs

ale snadno se na nějakou skupinu zapomene...

VBS skript může vypadat třeba takhle:

Option Explicit
On Error Resume Next

Dim objShell, objNetwork, Args, strComp, strUser, strGroup, i

Set objShell   = WScript.CreateObject("WScript.Shell")
Set objNetwork = WScript.CreateObject("WScript.Network")
Set Args       = Wscript.Arguments

strComp        = objNetwork.ComputerName
strUser        = objNetwork.UserName
strGroup       = Args(0)


' WScript.Echo strUser + "/" + strGroup + "@" + strComp

' ----------------------------------------------------------
' Mapovani sitovych disku
' ----------------------------------------------------------

If strComp = "NEJAKYSPECIALNIHOSTNAME" Then
  objNetwork.MapNetworkDrive "R:", "\\server\neco", true
  objNetwork.MapNetworkDrive "K:", "\\server\sw", true
  wscript.quit(0)
End If

' Essentials

  objNetwork.MapNetworkDrive "U:", "\\server\public\ucitele", true
  objNetwork.MapNetworkDrive "K:", "\\server\sw", true

' Per Group

If strGroup = "ucitele" Then
  objNetwork.MapNetworkDrive "S:", "\\server\public\sdilene", true
End If


Dim specialusers
specialusers = Array("user1", "jarda", "pepa")

If IsInArray(strUser, specialusers) Then
  objNetwork.MapNetworkDrive "R:", "\\server\resources", true
End If

' ----------------------------------------------------------
' Upozorneni na kvoty
' ----------------------------------------------------------

objShell.Run("\\server\netlogon\quota.vbs")

' ----------------------------------------------------------

wscript.quit(0)

' ----------------------------------------------------------
' Funkce
' ----------------------------------------------------------

Function IsInArray(str, array)
  Dim I
  IsInArray = false
  For Each I In array
    If I = str Then IsInArray = true
  Next
End Function