Administrace komentářů

Předem, bo mám N notebooků s 'HOME' edicemi Windows v síti, tak zatím na doménu kašlu, a připojuji disky rúčo baťákem, který může být klidně přihlašovacím skriptem. Podobné řešení jako vy jsem chtěl implementovat, ale bohudík všechny víceuživatelské jednoprofilové PC mám pod linuxem, takže jsem v pohodě a ani nevím jak bych to řešil v multijazyčném prostředí (Cz, En, Es, De, Hu, Ru) - tedy vím, ale to by bylo peněz za „Ultimate“.

K tématu, stačí Vám jeden dialog který se dotáže na jméno a heslo, a předá jej universálnímu baťáku jako dva parametry a přes NET USE to připojíte - to lze udělat během ½ hodiny, nebo jak je zde již uvedená hezká utilitka.

Nicméně:
<joke>
»Správně« by jste to měl udělat scriptovacími vyspělýmí technologiemi M$, aby to bylo čisté:

 Dim objIE
 Set objIE = CreateObject( "InternetExplorer.Application" )
 objIE.Navigate "about:blank"
 objIE.Document.Title = "Password"
 objIE.ToolBar        = False
 objIE.Resizable      = False
 objIE.StatusBar      = False
 objIE.Width          = 320
 objIE.Height         = 250

 With objIE.Document.ParentWindow.Screen
     objIE.Left = (.AvailWidth  - objIE.Width ) \ 2
     objIE.Top  = (.Availheight - objIE.Height) \ 2
 End With

 Do While objIE.Busy
     WScript.Sleep 200
 Loop

 objIE.Document.Body.InnerHTML = "<DIV align=""center""><P>" & "Prihlas se" _
                               & "</P>" & vbCrLf _
                               & "<P><INPUT TYPE=""text"" SIZE=""20"" " _
                               & "ID=""Username""></P>" & vbCrLf _
                               & "<P><INPUT TYPE=""password"" SIZE=""20"" " _
                               & "ID=""Password""></P>" & vbCrLf _
                               & "<P><INPUT TYPE=""hidden"" ID=""OK"" " _
                               & "NAME=""OK"" VALUE=""0"">" _
                               & "<INPUT TYPE=""submit"" VALUE="" OK "" " _
                               & "OnClick=""VBScript:OK.Value=1""></P></DIV>"
 ' Make the window visible
 objIE.Visible = True
 ' Wait till the OK button has been clicked
 Do While objIE.Document.All.OK.Value = 0
     WScript.Sleep 200
 Loop
 Dim passwd
 Dim usrnm
 usrnm = objIE.Document.All.Username.Value
 passwd = objIE.Document.All.Password.Value
 objIE.Quit
 Set objIE = Nothing


WScript.Echo "Uziv: " & usrnm & " Heslo: " & passwd
'Misto tohoto se da pripojit disk pomoci

'Dim objNetwork, strDriveLetter, strHomeServer
'strDriveLetter = "S:"
'strHomeServer = "\\server\home\"
'
'Set objNetwork = CreateObject("WScript.Network")
'strUserName =objNetwork.UserName
'objNetwork.MapNetworkDrive strDriveLetter, strHomeServer, usrnm, passwd

PS: vlastní připojení je zakomentované a neodzkoušené - jen to zobrazí jméno a heslo :)
</joke>