OpenOffice Impress - škálování obrázku na velikost slidu

11.3.2009 12:14 | Přečteno: 1308× | OpenOffice | poslední úprava: 11.3.2009 12:47

Funkce uveřejněného makra: Vybraný obrázek (či jiný objekt) zvětší tak, aby se právě vešel na velikost slidu. Přitom ponechá původní poměr stran.

Podotýkám, že nikdy nebylo mým přáním studovat dokumentaci k OpenOffice Basic. A ani v tomto směru nehodlám směřovat svůj osud. Nicméně když jsem se ocitl před problémem, který bez napsání vlastního makra vyřešit nešel, co mi zbývalo.

Dostal jsem do ruky powerpointovou prezentaci (mimochodem ve výsledku úspěšnou), která kromě textových slidů obsahovala velké množství samostatných fotografií. Nicméně autor je ponechal tak, jak je vložil, tudíž v závislosti na rozlišení značně rozsah slidu přesahovaly či ho naopak nezakrývaly celý. Půl hodiny jsem trávil hledáním řešení přes standardní funkce OO, nicméně k výsledku jsem se nedobral. Ani google mi v tomto nepomohl (nenabídl ani makro). Než manuálně (a nepřesně) měnit roztahovat desítky obrázků, rozhodl jsem se sáhnout k systémovějšímu řešení.

Výsledkem je makro CenterScaledObject, které přesně plní zadání: je-li v OpenOffice Impress (či OpenOffice Draw) vybraný právě jeden objekt, po spuštění makra jej zvětší na velikost slidu, zachová poměr velikostí a umístí jej do středu. Je-li vybráno více objektů nebo žádný, ohlásí chybu.

Uveřejňuji zde makro v dobré víře, že by někomu mohlo být užitečné, případně že někdo v něm najde mušky, které by stály za opravení nebo vylepšení (např. je možné, aby různé slidy v prezentaci měly různou velikost => má smysl se ptát po slidu, na kterém obrázek je?).

'Scales selected object so that it just fits into the slide while keeping the aspect ratio.
Sub CenterScaledObject
	'Get selection
	oSelection = ThisComponent.CurrentSelection

	'Check for errors - either there is nothing selected or there are too many objects
	If isNull(oSelection) Then
		MsgBox("No object selected.")
	ElseIf oSelection.count <> 1 Then
		MsgBox("Too many objects selected - select just one.")
	'Now there should be only one object selected    	
	Else
		'The selected object will be represented by selected
		selected = oSelection.getByIndex(0)
		
		'Select the page so that we know to which to scale	
		page = ThisComponent.drawPages(0)
		'***TODO: Possibly there are slides of different sizes?
		'***However we take the size of the first one

		'Get actual size of the object
		w = selected.Size.Width
		h = selected.Size.Height
		
		Dim size As New com.sun.star.awt.Size    'New size
		Dim point As New com.sun.star.awt.Point   'New position
		
		'Default values - only one will change
		point.x = 0
		point.y = 0
		
		'Calculate the position and size
		If (w / h) > (page.Width / page.Height) Then
			size.Width = page.Width
			size.Height = Int(page.Width * h / w)
			point.y = Int((page.Height - size.Height) / 2)
		Else
			size.Height = page.Height
			size.Width = Int(page.Height * w / h)
			point.x = Int((page.Width - size.Width) / 2)
		End If
		
		'Resize
		selected.setSize(size)
		'And move to the center
		selected.Position = point
		'DONE
	End if
End Sub

       

Komentáře